image: New image without GPLv3 added

- Most of the base-utils have been replaced by the busybox variant
- The libreadline is used by a lot of applications. Where possible
libreadline was removed via PACKAGECONFIG. Also editline was added,
which can function as an drop-in replacement to readline.
- The support for Python 2 was removed, because it depends on GPLv3
libraries. Besides the dependencies, Python 2 is EOL since 2020.
- The networkmanager is still not buildable against editline and was
removed (see meta-guf-distro).
- GPLv3 software that isn't vital for the system was moved to a new
FEATURE_PACKAGES group in meta-guf-distro.

BCS 746-000741

conf/layer.conf

+BBPATH .= ":${LAYERDIR}"
+
+BBFILES += " \
+    ${LAYERDIR}/recipes-*/*/*.bb \
+    ${LAYERDIR}/recipes-*/*/*.bbappend \
+    ${LAYERDIR}/recipes-*/*/*/*.bb \
+    ${LAYERDIR}/recipes-*/*/*/*.bbappend \
+"
+
+BBFILE_COLLECTIONS += "seconorth-nogplv3"
+BBFILE_PATTERN_seconorth-nogplv3 := "^${LAYERDIR}/"
+BBFILE_PRIORITY_seconorth-nogplv3 = "9"
+
+LAYERSERIES_COMPAT_seconorth-nogplv3 = "dunfell"
+

recipes-bsp/images/seco-image-nogplv3.bb

+SUMMARY = "Standard SECO Northern Europe Yocto Image without GPLv3 Software"
+
+require seco-image.inc
+inherit populate_sdk_qt5
+
+INCOMPATIBLE_LICENSE = "GPL-3.0 LGPL-3.0 AGPL-3.0"
+
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+# @INFO: package-management was removed because rpm depends on bash
+# If we need package-management, we might use another package format (e.g. deb).
+
+# @INFO: tools-debug was removed because it depends on GPLv3
+
+IMAGE_FEATURES += " \
+    hwcodecs \
+    splash \
+    ssh-server-openssh \
+"
+
+IMAGE_INSTALL_GRAPHICS += " \
+    packagegroup-guf-graphics-wayland \
+    packagegroup-guf-graphics-fonts \
+"
+
+IMAGE_INSTALL_GUF += " \
+    guf-show-demo \
+    packagegroup-guf-small \
+    packagegroup-guf-debug \
+"
+
+IMAGE_INSTALL_GUF_append_imx8mpguf += " \
+    guf-show-demo2 \
+"
+
+IMAGE_INSTALL_MULTIMEDIA += " \
+    packagegroup-guf-multimedia \
+"
+
+IMAGE_INSTALL_QT += " \
+    packagegroup-guf-qt5 \
+    packagegroup-guf-qt5-tools \
+    packagegroup-guf-qt5-tests \
+    packagegroup-guf-qt5-translations \
+"
+
+IMAGE_INSTALL_PYTHON += " \
+    packagegroup-guf-python \
+"
+
+IMAGE_INSTALL_TEST += " \
+    packagegroup-guf-tests-full \
+"
+
+IMAGE_INSTALL_CONNECTIVITY += " \
+    packagegroup-guf-connectivity \
+"
+
+CORE_IMAGE_EXTRA_INSTALL += " \
+    ${IMAGE_INSTALL_GRAPHICS} \
+    ${IMAGE_INSTALL_GUF} \
+    ${IMAGE_INSTALL_MULTIMEDIA} \
+    ${IMAGE_INSTALL_QT} \
+    ${IMAGE_INSTALL_PYTHON} \
+    ${IMAGE_INSTALL_TEST} \
+    ${IMAGE_INSTALL_CONNECTIVITY} \
+"
+
+PACKAGE_EXCLUDE = " \
+    bash \
+    coreutils \
+    cpio \
+    diffutils \
+    dosfstools \
+    ed \
+    findutils \
+    fio \
+    gawk \
+    gdb \
+    gdbm \
+    grep \
+    gzip \
+    inetutils \
+    inetutils-telnet \
+    inetutils-tftp \
+    inetutils-traceroute \
+    nano \
+    parted \
+    patch \
+    perl \
+    postgresql \
+    qt-kiosk-browser \
+    readline \
+    libreadline8 \
+    sed \
+    sqlite \
+    sqlite3 \
+    tar \
+    time \
+    wget \
+    which \
+    wireguard-tools \
+"
+
+CORE_IMAGE_EXTRA_INSTALL_append = " \
+    dash \
+    editline \
+"
+

recipes-bsp/images/seco-image.inc

+#
+# SPDX-License-Identifier: Apache-2.0
+#
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+HOMEPAGE = "https://www.seco.com"
+
+IMAGE_BOOT_FILES = "${KERNEL_IMAGETYPE}"
+
+inherit core-image extrausers features_check
+

recipes-connectivity/bind/bind_%.bbappend

+PACKAGECONFIG_remove = "readline"
+

recipes-connectivity/bluez5/bluez5_%.bbappend

+PACKAGECONFIG_remove = "readline"
+

recipes-connectivity/networkmanager/networkmanager_%.bbappend

+DEPENDS_append = " editline "

recipes-connectivity/socat/socat_%.bbappend

+PACKAGECONFIG_remove = "readline"
+

recipes-devtools/editline/editline_1.17.bb

+#
+# SPDX: BSD-3-Clause
+#
+
+SUMMARY = "Small line editing library"
+DESCRIPTION = "Can be linked into almost any program to provide command line editing \
+and history functions. Usable as drop-in replacement for readline."
+HOMEPAGE = "https://github.com/troglobit/editline"
+
+SECTION = "devel"
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=f2a8150e04f36fb9d499fbb6495244ea"
+
+SRC_URI = "git://github.com/troglobit/editline.git;protocol=https;branch=master"
+SRCREV = "ecabef273ebf4193c5d6aff196de1c204169bc52"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig autotools
+
+do_install_prepend () {
+	install -d ${D}${includedir}/editline
+	ln -sf ${includedir}/editline.h ${D}${includedir}/editline/history.h
+}
+

recipes-devtools/python/python3_%.bbappend

+PACKAGECONFIG_remove = "gdbm readline"
+

recipes-extended/packagegroups/packagegroup-core-base-utils.bbappend

+RDEPENDS_${PN}_remove = " \
+    bash \
+    coreutils \
+    cpio \
+    diffutils \
+    ed \
+    findutils \
+    gawk \
+    grep \
+    gzip \
+    inetutils \
+    inetutils-ping \
+    inetutils-telnet \
+    inetutils-tftp \
+    inetutils-traceroute \
+    parted \
+    patch \
+    sed \
+    tar \
+    time \
+    wget \
+    which \
+"
+