Initial commit

Add initial support for C61 with:
 - kernel linux-fslc 5.10.10
 - uboot  u-boot-imx 2020.04

COPYING.MIT

+Permission is hereby granted, free of charge, to any person obtaining a copy 
+of this software and associated documentation files (the "Software"), to deal 
+in the Software without restriction, including without limitation the rights 
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell 
+copies of the Software, and to permit persons to whom the Software is 
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in 
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, 
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN 
+THE SOFTWARE.

README

+This README file contains information on the contents of the meta-seco-imx layer.
+
+Please see the corresponding sections below for details.
+
+Dependencies
+============
+
+  URI: <first dependency>
+  branch: <branch name>
+
+  URI: <second dependency>
+  branch: <branch name>
+
+  .
+  .
+  .
+
+Patches
+=======
+
+Please submit any patches against the meta-seco-imx layer to the xxxx mailing list (xxxx@zzzz.org)
+and cc: the maintainer:
+
+Maintainer: XXX YYYYYY <xxx.yyyyyy@zzzzz.com>
+
+Table of Contents
+=================
+
+  I. Adding the meta-seco-imx layer to your build
+ II. Misc
+
+
+I. Adding the meta-seco-imx layer to your build
+=================================================
+
+Run 'bitbake-layers add-layer meta-seco-imx'
+
+II. Misc
+========
+
+--- replace with specific information about the meta-seco-imx layer ---

conf/layer.conf

+# We have a conf and classes directory, add to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+# We have recipes-* directories, add to BBFILES
+BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
+            ${LAYERDIR}/recipes-*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "meta-seco-imx"
+BBFILE_PATTERN_meta-seco-imx = "^${LAYERDIR}/"
+BBFILE_PRIORITY_meta-seco-imx = "6"
+
+LAYERDEPENDS_meta-seco-imx = "core"
+LAYERSERIES_COMPAT_meta-seco-imx = "dunfell"

conf/machine/seco-imx8mm-c61.conf

+#@TYPE: Machine
+#@NAME: SECO C61 NXP i.MX 8M Mini EVK with LPDDR4
+#@SOC: i.MX8MM
+#@DESCRIPTION: Machine configuration for NXP i.MX 8M Mini SECO C61 with LPDDR4
+#@MAINTAINER: Alberto Merciai <alberto.merciai@seco.com>
+#@MAINTAINER: Ettore Chimenti <ettore.chimenti@seco.com>
+
+MACHINEOVERRIDES =. "mx8:mx8m:mx8mm:"
+IMX_DEFAULT_BSP = "mainline"
+
+require conf/machine/include/imx-base.inc
+require conf/machine/include/tune-cortexa53.inc
+
+KERNEL_DEVICETREE_BASENAME = "seco-imx8mm-c61"
+KERNEL_DEVICETREE_append_use-nxp-bsp = " \
+	freescale/${KERNEL_DEVICETREE_BASENAME}.dtb \
+"
+KERNEL_DEVICETREE_append_use-mainline-bsp = " \
+	freescale/${KERNEL_DEVICETREE_BASENAME}.dtb \
+"
+PREFERRED_PROVIDER_virtual/kernel = "linux-seco-fslc" 
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-seco-imx"
+PREFERRED_PROVIDER_u-boot = "u-boot-seco-imx"
+
+UBOOT_CONFIG ??= "emmc"
+UBOOT_CONFIG_BASENAME = "seco_imx8mm_c61"
+UBOOT_CONFIG[emmc] = "${UBOOT_CONFIG_BASENAME}_defconfig"
+SPL_BINARY = "spl/u-boot-spl.bin"
+
+ATF_MACHINE_NAME = "bl31-imx8mm.bin"
+SOC_TARGET = "iMX8MM"
+
+# Set u-boot DTB
+UBOOT_DTB_NAME = "seco-imx8mm-c61.dtb"
+
+DDR_FIRMWARE_NAME = " \
+	lpddr4_pmu_train_1d_imem.bin \
+	lpddr4_pmu_train_1d_dmem.bin \
+	lpddr4_pmu_train_2d_imem.bin \
+	lpddr4_pmu_train_2d_dmem.bin \
+"
+
+IMXBOOT_TARGETS = "flash_evk"
+
+# Set Serial console
+SERIAL_CONSOLES = "115200;ttymxc1"
+
+LOADADDR = ""
+UBOOT_SUFFIX = "bin"
+UBOOT_MAKE_TARGET = ""
+IMX_BOOT_SEEK = "33"

recipes-bsp/u-boot/u-boot-seco-imx-common.inc

+DESCRIPTION = "i.MX U-Boot suppporting i.MX SECO boards."
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRCBRANCH = "seco/develop/imx_5.4.70_2.3.0-imx8m"
+SRC_URI = "git://git.seco.com/pub/i.mx/yocto/5.x/uboot-seco-imx.git;protocol=https;branch=${SRCBRANCH}"
+#SRCREV = "c3c3f02063127b5b00378ef95795333427e40939"
+SRCREV = "${AUTOREV}"
+
+DEPENDS += "flex-native bison-native bc-native dtc-native firmware-imx"
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/build"
+
+inherit fsl-u-boot-localversion
+
+LOCALVERSION ?= "-${SRCBRANCH}"
+
+BOOT_TOOLS = "imx-boot-tools"
+

recipes-bsp/u-boot/u-boot-seco-imx_2020.04.bb

+# Copyright (C) 2013-2016 Freescale Semiconductor
+# Copyright 2018 (C) O.S. Systems Software LTDA.
+# Copyright (C) 2017-2020 NXP
+
+require recipes-bsp/u-boot/u-boot.inc
+require u-boot-seco-imx-common.inc
+
+PROVIDES += "u-boot"
+
+do_deploy_append_mx8m() {
+    # Deploy the mkimage, u-boot-nodtb.bin and fsl-imx8m*-XX.dtb for mkimage to generate boot binary
+    if [ -n "${UBOOT_CONFIG}" ]
+    then
+        for config in ${UBOOT_MACHINE}; do
+            i=$(expr $i + 1);
+            for type in ${UBOOT_CONFIG}; do
+                j=$(expr $j + 1);
+                if [ $j -eq $i ]
+                then
+                    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+                    install -m 0777 ${B}/${config}/arch/arm/dts/${UBOOT_DTB_NAME}  ${DEPLOYDIR}/${BOOT_TOOLS}
+                    install -m 0777 ${B}/${config}/u-boot-nodtb.bin  ${DEPLOYDIR}/${BOOT_TOOLS}/u-boot-nodtb.bin-${MACHINE}-${UBOOT_CONFIG}
+                fi
+            done
+            unset  j
+        done
+        unset  i
+    fi
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"

recipes-kernel/linux/linux-seco-fslc.inc

+# Copyright (C) 2012-2015 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require recipes-kernel/linux/linux-imx.inc
+
+DEPENDS += "lzop-native bc-native"
+
+SRC_URI = "git://git.seco.com/pub/i.mx/yocto/5.x/linux-seco-fslc.git;branch=${SRCBRANCH}"
+
+KBUILD_DEFCONFIG_seco-imx8mm-c61 = "seco_imx8_defconfig"
+
+LOCALVERSION = "-fslc"

recipes-kernel/linux/linux-seco-fslc_5.10.bb

+# Copyright (C) 2012-2019 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+#
+# SPDX-License-Identifier: MIT
+#
+
+SUMMARY = "SECO FSL Community BSP Linux mainline based kernel with backported features and fixes"
+DESCRIPTION = "Linux kernel based on mainline kernel used by FSL Community BSP in order to \
+provide support for some backported features and fixes, or because it was applied in linux-next \
+and takes some time to become part of a stable version, or because it is not applicable for \
+upstreaming."
+
+include linux-seco-fslc.inc
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+# PV is defined in the base in linux-imx.inc file and uses the LINUX_VERSION definition
+# required by kernel-yocto.bbclass.
+#
+# LINUX_VERSION define should match to the kernel version referenced by SRC_URI and
+# should be updated once patchlevel is merged.
+LINUX_VERSION = "5.10.10"
+
+SRCBRANCH = "seco/develop/v5.10.10"
+SRCREV = "f6e1a93ee27713241d0cef4a9d6180826306e20c"
+
+COMPATIBLE_MACHINE = "(mxs|mx5|mx6|mx8|vf|use-mainline-bsp)"